扁舟重过九青莲，极目空明思浩然。可是画工烦刻画，只因山骨偶枝骈。风高迥认龙腾海，云散初疑剑插天。剩采太湖嵌孔石，南窗排列伫飞仙。 -------[宋] 孔武仲《九华山》

排序的函数，如果大家对Excel基础函数比较了解的话，应该都知道RANK函数。

我们在实际工作中，常常把RANK函数用于对一列数据的基本排序，即从大到小的排序方法，那你还知道它的其他什么用法吗？

今天就给大家系统的分享下RANK函数的用法，分享的内容主要为以下这6种技巧。

1、升序排列

2、降序排列

3、多列数据排名

4、多条件排名

5、不出现相同排名（以出现顺序进行优先排列）

6、跨多表排名

首先我们先了解下RANK函数的基本定义。

RANK(number,ref,order)

number：要查找排名的数值

ref：参与排名的单元格区域，非数字值将被忽略。

order：代表排位方式，0或不填的时候为降序排列，即最大值为第一名；非零时为升序排列，即最小值为第一名

知道了RANK函数的基本定义，下面我们来看下它的具体使用技巧。

技巧一、升序排列

比如我们把下面的的数据，按销量由小到大进行升序排列，要如何做呢？

只需要在E2单元格输入如下公式，即可。

=RANK(D2,$D$2:$D$24,1)

按RANK函数的参数定义，当order，非0时即为升序排列。

技巧二、降序排列

同样是使用如上的数据，按销量对数据从大到小进行排序，最大值即为1。

E2单元格公式：

=RANK(D2,$D$2:$D$24)

技巧三、多列数据排名

比如如下样式，我们有多列数据，我们想将多列不同的数据，同样按销量大小进行排名，要如何进行操作呢？

操作步骤：

1、选中A1:I8数据区域，按Ctrl+G定位

2、定位条件，选中【空值】，点击确定

3、输入如下公式，然后按Ctrl+Enter填充，即可

=RANK(B2,($B$2:$B$8,$E$2:$E$8,$H$2:$H$8))

Ps:特别需要注意的是，我们的参数2Number是3个区域的合并，中间是使用英文逗号","连接。

技巧四、多列条件排名

我们有如下的数据，可以看到部分同学的物理化学的总分是一样的，比如"赵云"，"李白"，"妲己"都是179分，如果总分一样，我们再依物理成绩的大小进行排序，这要如何去做呢？

操作步骤：

1、首先我们在E列增加一个辅助列，输入如下公式：

=D2*1000+B2

公式理解：

当我们把总分进行放大1000倍的时候，总分之间的大小是不变的，再加上物理的成绩，即实现了大小区分

2、在F列输入公式：

=RANK(E2,$E$2:$E$10)

3、最后再隐藏辅助列即实现了多条件排序

技巧五、不出现相同排名（以出现顺序进行优先排列）

首先我们要理解此技巧是什么意思呢？

我们在实际排序的时候，偶尔会遇到数据是相同的，我们在进行排名的时候，这些排名往往是相同的，就比如如下案例：

"黄忠""程咬金"的销量相同，排名都为第2，那如果我不想让它出现相同的排名，而是以"黄忠"先参与排名，排名为2，"程咬金"后参与排名，排名为3，其他类似，这样的排名要怎么做？

很简单，主要我们在参与排名的时候，增加个计数统计即可。

在D2输入公式：

=RANK(B2,$B$2:$B$11)+COUNTIF($B$2:B2,B2)-1

可以发现，排名是按出现的顺序依次进行的。

这个函数的关键在于COUNTIF函数的应用，COUNTIF($B$2:B2,B2)-1公式中第一个B2是绝对引用的，当公式向下拖动时，即可以得到相应的数据是第几次出现的，然后再加上原始排名即可。

技巧六、跨多表排名

我们有下面的4张工作表，每个工作表都有一部分数据，其中D列均为销量，我们如何根据所有的表进行销量排名呢？

我们点击E2单元格，输入如下RANK函数：

=RANK(D2,销售1部:销售4部!$D$2:$D$7)

number选择D2，输入ref内容时，点击"销售1部"，按住Shift键，再点击"销售4部",选择D2:D7单元格,按F4把区域绝对引用。

其他各个工作表同样输入此公式即可。

Ps:特别需要注意的是，引用的区域必须是所有工作表里行数范围最大的，否则统计数据不是所有的内容

其他内容

最后再给大家分享下RANK函数家族的其他函数，RANK.EQ和RANK.AVG

各个函数支持的Excel版本及参数含义如下:

具体的操作可看下面的图：

RANK.EQ和RANK的用法一致，RANK.AVG返回数据的平均排位，比如上面的数据"赵云""李白"的排名使用RANK及RANK.EQ函数均为3，而RANK.AVG函数为3.5，及排名为第3、4名的平均值，更多需要需要大家再发掘下。